オリジナル版をいじっているうちに修正箇所がたくさん見つかり、直しすぎて個別にpull requestすることが困難になり、途中で作者のrupaさんにはforkの存在とそこそこ詳細な変更点リストをメールしたんだけど時すでに遅し。ほかにもforkがたくさんありすぎてうんざりだったかも。とはいえbashの補完は壊れているしzshの補完も古くて（compsys）いまいちだし、というわけでフィードバックについては気にせずにコアのアルゴリズム部以外を大幅に書き直しました。

ついでにcdの補完候補にzのスタック（ディレクトリ移動履歴に基づいてスコアリングされたディレクトリリスト）を含めるようにしたので、「zが使えるホストでだけzを使う」とか、「通常の移動はcd¹、よく行くところへの移動はz」なんていう悲しい使い分けは不要になりました。普通にcdを使っていれば、zが有効なら補完候補の上位によく行くディレクトリが現れるという空気のような存在です。

ただし、bashでは補完候補の出現順序を制御する方法がない²ため、cdにおいてはマッチするディレクトリがないときだけzのスタックから補完します。（常に含めてしまうと、辞書順ソートのおかげでうざいことになる）
ていうかzshを使えばいいと思います。

インストールは~/.bashrcや~/.zshrcに一行足すだけなので、READMEを読んで使ってみて。

1. cdはCDPATHを見るとか-に戻れるとかcdable_varsとかいろいろ特徴があるのでzだけでは済まない。
2. よね？あったら教えて。compopt -o nosortとかあればいいのに。

The post “z”のfork「knu-z」v2.0をリリース appeared first on 工夫と趣向と分別と。.

The post Gitを使っていて zsh: no matches found: HEAD^ などと言われない方法 appeared first on 工夫と趣向と分別と。.

(defun kill-region-or-backward-kill-word (&optional arg)
  "Kill a region or a word backward."
  (interactive)
  (if mark-active
      (kill-region (mark) (point))
    (backward-kill-word (or arg 1))))
(global-set-key "\C-w" 'kill-region-or-backward-kill-word)

zshで同じことをするならこう。

tcsh-backward-delete-word () {
	local WORDCHARS="${WORDCHARS:s#/#}"
	zle backward-delete-word
    }
    zle -N tcsh-backward-delete-word
    kill-region-or-tcsh-backward-delete-word () {
        if [ $MARK -eq 0 ]; then
            tcsh-backward-delete-word
        else
            zle kill-region
            MARK=0
        fi
    }
    zle -N kill-region-or-tcsh-backward-delete-word
    bindkey '^W' kill-region-or-tcsh-backward-delete-word

zshにはtransient-mark-modeはないので、マーク位置がバッファの先頭だったらマークされていないと見なす。
けっこう便利。
※その後変数REGION_ACTIVEが導入されたので、今は以下でOK。（2013-10-21追記）

kill-region-or-tcsh-backward-delete-word () {
        if ((REGION_ACTIVE)); then
            zle kill-region
        else
            tcsh-backward-delete-word
        fi
    }

The post Making Ctrl+W a tad smarter appeared first on 工夫と趣向と分別と。.

　たとえば、「alias -g -- --mydb3='-h mydb3 -uadmin -p'」のように定義しておくと、「mysql --mydb3 」や「mysqldump --mydb3 --no-data blog」など、MySQLの接続情報の指定が楽になる。しかも、aliasなのでその前後でちゃんとzshのコマンドライン補完が利くのがうれしいところ。

　同様に、find(1)用に-cvs-excludeを定義してみた。

exclude_patterns=(
    RCS SCCS CVS CVS.adm RCSLOG 'cvslog.*' tags TAGS .make.state
    .nse_depinfo '*~' '#*' '.#*' ',*' '_$*' '*$'
    \*.{old,bak,BAK,orig,rej,del-\*,a,olb,o,obj,so,exe,Z,elc,ln}
    core .svn .bzr
)

alias -g -- -cvs-exclude='\( \! \( \( '"${(j/ -o /@)${(@q)exclude_patterns}/()/-name }"' \) -prune \) \)'

unset exclude_patterns

これで、「find ~/src/ruby -cvs-exclude -mtime -1」などと使えるわけだ。

　このほか、よく使うconfigureオプションをまとめたものを定義したりしても便利だと思う。もちろん、globalだけにあまりにありふれた名前は避けたいが、普通のalias同様にバックスラッシュで展開を避けることができるので、うっかりしても痛い目を見ない自信があるなら思い切った名前にしてしまってもいいと思う。

The post zshのglobal alias appeared first on 工夫と趣向と分別と。.

make_p () {
    local t s
    t="$1"; shift

    [ -f $t ] || return 0

    for s; do
	[ $s -nt $t ] && return 0
    done

    return 1
}

cache_hosts_file="$ZDOTDIR/.cache_hosts"
known_hosts_file="$HOME/.ssh/known_hosts"

print_cache_hosts () {
    if [ -f $known_hosts_file ]; then
	awk '{ if (split($1, a, ",") > 1) for (i in a) { if (a[i] ~ /^[a-z]/) print a[i] } else print $1 }' $known_hosts_file
    fi
}

update_cache_hosts () {
    print_cache_hosts | sort -u > $cache_hosts_file
}

make_p $cache_hosts_file $known_hosts_file && update_cache_hosts

_cache_hosts=( $(< $cache_hosts_file) )

　ずっとこの便利さを当たり前だと思っていて、IRCで指摘されるまで自分が書いた上のコードのおかげであることを忘れていた。せっかくなのでここで紹介しておく。

[後日、若干の改善のため微修正しました。(2004-04-25)]

The post zshのホスト名補完強化 appeared first on 工夫と趣向と分別と。.