というのも、Emergeにはemerge-files-with-ancestor-commandという便利なものがあり、「マージが終わったらマージ結果を保存して即終了」ということが一発で出来てしまうのだが、Ediffの方にはそういうものがない。こいつはマージを終了してもろくに片付けもせず、全部ほったらかしという行儀の悪さだ。
そういうわけで、まずはEdiffのediff-merge-{files,buffers}が終わったら起動前のウィンドウ設定を復元するようにしてみる。これは比較的簡単。[2013-01-23改訂:フックにappendフラグを指定]

(eval-after-load "ediff"
  '(progn
     ; save and restore window configuration
     (defvar my-ediff-saved-window-configuration nil "Saved window configuration for ediff")
     (defun my-ediff-save-window-configuration ()
       (setq my-ediff-saved-window-configuration (current-window-configuration)))
     (add-hook 'ediff-before-setup-hook 'my-ediff-save-window-configuration)
     (defun my-ediff-restore-window-configuration ()
       (set-window-configuration my-ediff-saved-window-configuration))
     (add-hook 'ediff-suspend-hook 'my-ediff-restore-window-configuration t)
     (add-hook 'ediff-quit-hook 'my-ediff-restore-window-configuration t)))

次に、Ediffが新たに開いたファイルのバッファをマージ終了時に自動的に閉じる、および、マージ終了時に自動的にセーブしつつEmacsフレームを閉じる「バッチ版ediff-merge-files-with-ancestor」を加える。[2013-01-23改訂:ediff-filesに影響を与えるなどおかしかったので大幅修正; 続きはGitHubで]

(eval-after-load "ediff"
  '(progn
     ; batch mode (for use from git mergetool etc.)
     (ediff-defvar-local my-ediff-batch-mode-p nil "True if in batch mode")
     (ediff-defvar-local my-ediff-close-on-quit nil "True if the buffer should be closed on quit.")

     (defun my-ediff-batch-mode (&optional mode)
       (ediff-with-current-buffer ediff-buffer-A
                                  (case mode
                                    (set
                                     (setq my-ediff-batch-mode-p t))
                                    (unset
                                     (prog1 my-ediff-batch-mode-p
                                       (setq my-ediff-batch-mode-p nil)))
                                    (t
                                     my-ediff-batch-mode-p))))

     (defadvice ediff-find-file (around
                                 mark-newly-opened-buffers
                                 (file-var buffer-name &optional last-dir hooks-var)
                                 activate)
       (let* ((file (symbol-value file-var))
              (existing-p (and find-file-existing-other-name
                               (find-buffer-visiting file))))
         ad-do-it
         (or existing-p
             (ediff-with-current-buffer (symbol-value buffer-name)
                                        (setq my-ediff-close-on-quit t)))))

     (defun my-ediff-save-merge ()
       (if (my-ediff-batch-mode)
           (let ((file ediff-merge-store-file))
             (if file
                 (ediff-with-current-buffer ediff-buffer-C
                   (set-visited-file-name file t)
                   (save-buffer))))
         (ediff-maybe-save-and-delete-merge)))

     (remove-hook 'ediff-quit-merge-hook 'ediff-maybe-save-and-delete-merge)
     (add-hook 'ediff-quit-merge-hook 'my-ediff-save-merge)

     (defadvice ediff-cleanup-mess (around
                                    support-batch-mode
                                    ()
                                    activate)
       (let ((batch-p (my-ediff-batch-mode 'unset))
             (buffers (list ediff-buffer-A ediff-buffer-B ediff-ancestor-buffer))
             (buffer-C ediff-buffer-C))
         ad-do-it
         (dolist (buffer buffers)
           (ediff-with-current-buffer buffer
             (and my-ediff-close-on-quit (kill-buffer))))
         (when batch-p
           (ediff-kill-buffer-carefully buffer-C)
           (delete-frame))))

     (defun ediff-merge-files-with-ancestor-in-batch-mode
       (file-A file-B file-ancestor &optional startup-hooks merge-buffer-file)
       (ediff-merge-files-with-ancestor
        file-A file-B file-ancestor
        (cons (function (lambda () (my-ediff-batch-mode 'set))) startup-hooks)
        merge-buffer-file))))

(autoload 'ediff-merge-files-with-ancestor-in-batch-mode "ediff")

これで、~/.gitconfigにこんな風に書けばgit mergetoolで瞬時にEdiffが起動し、マージが済んだらq, yで即コマンドラインに帰ってくる。既存Emacsセッションにゴミバッファも残らない。

[merge]
	tool = ediff
[mergetool "ediff"]
	cmd = emacsclient -a \"\" -t -e \"(ediff-merge-files-with-ancestor-in-batch-mode \\\"$LOCAL\\\" \\\"$REMOTE\\\" \\\"$BASE\\\" nil \\\"$MERGED\\\")\"

あとは、たとえばラッパースクリプトを用意して、「<<<<<<<」などの行が残っていたらマージ失敗とするとか、好きに改良すると良い。

参考記事

• emacs – Using ediff as git mergetool – Stack Overflow

The post git mergetoolでEmacsのediff-merge-files-with-ancestorを呼び出す appeared first on 工夫と趣向と分別と。.

• Shift+矢印による範囲選択
• 範囲選択状態でBS/DELを押すと選択範囲をまるごと消去
• 範囲選択状態でキー入力やペーストを行うと選択範囲まるごと上書きされる
• 視覚化された矩形範囲選択モード（C-w, M-w, C-yなど通常の範囲選択と同様の操作性）
• 矩形範囲選択モードでの複数行同時操作（文字入力、文字削除、連番挿入等）
• Windows互換のCtrl+Z,X,C,V（※）

Emacs 22.1.1から標準添付されているので、試したければ何も設定せずにM-x cua-modeで使える。上記のうち最後の機能は率直に言って邪魔なのだが、これはWindowsから来た人をターゲットに据えた本モードの目玉機能のようで、デフォルトでオンになっている。ために、Emacsに慣れた人ほど、少し触ったところで戸惑いを感じて敬遠しがちなのが残念なところ。
このcua-modeを起動時から有効化するには、M-x customize-group RET cua RETとしてcustomize画面に入り、”Cua Mode”を”on”にする。私のように上記※が不要だと思う人は”Cua Enable Cua Keys”を”Disabled”にして、”Set for current session”を押す。これでcua-modeが（一時的に）有効な状態になるので、他のバッファで挙動を確認してみよう。満足したら、customizeバッファに戻って”Save for future sessions”を押せば恒久保存される。
さて、Shift+矢印による範囲選択を試してみただろうか。GUI上のEmacsで動くのは当然として、xterm互換ターミナル上のEmacsでも動くのには軽い感動を覚えたかもしれない。ただし、Emacsのバグで、S-left, S-right, S-downは動くのになぜかS-upだけは期待通り動作せず、selectキーとして認識されてしまう。これは以下のようなコードで期待通り動くようになる。(ついでにendキーがおかしいのも直している)

(defadvice terminal-init-xterm (after fix-some-keys activate)
  (define-key input-decode-map "\e[1;2A" [S-up])
  (define-key input-decode-map "\e[4~" [end]))

ところで、矩形選択モードのトグルキーはデフォルトではC-RETだが、私はcua-toggle-global-markの方に割り当てられているC-S-SPCに変更している。これは、先のカスタマイズ画面で”Cua Rectangle Mark Key”をC-S-SPCに設定（入力欄でC-qを押してから設定したいキーコンボを押すのが楽）して保存すれば済むはずだが、cuaの初期化フローがおかしいため、以下のコードも必要のようだ。

(define-key cua-global-keymap cua-rectangle-mark-key 'cua-set-rectangle-mark)

cua-toggle-global-markの方は、カスタマイズ変数がないので以下のようにコードを書いてC->に設定している。

(define-key cua-global-keymap (kbd "C->") 'cua-toggle-global-mark)

なお、C-RET, C-S-SPC, C->などの特殊キーコンボをターミナル上で使うためにはターミナルエミュレータの設定が必要なので、こちらの記事を参考にされたい。
というわけでおしまい、でもいいのだけれど、矩形選択モードで単語単位の移動ができないのはちょっと不便だと思う私はこんな設定を施している。

(eval-after-load "cua-rect"
  '(progn
     (defun cua-resize-rectangle-move-bol ()
       "Resize rectangle to the BOL."
       (interactive)
       (while (not (bolp)) (backward-char)))
     (defun cua-resize-rectangle-move-eol ()
       "Resize rectangle to the EOL."
       (interactive)
       (while (not (eolp)) (forward-char)))
     (defun cua-resize-rectangle-right-word (n)
       "Resize rectangle to the right word."
       (interactive "p")
       (if (< n 0)
         (let ((pos (save-excursion (backward-word (- n)) (point))))
           (while (< pos (point)) (backward-char)))
         (let ((pos (save-excursion (forward-word n) (point))))
           (while (< (point) pos) (forward-char)))))
      (defun cua-resize-rectangle-left-word (n)
        "Resize rectangle to the left word."
        (interactive "p")
        (cua-resize-rectangle-right-word (- n)))
      (defadvice cua--init-rectangles
        (after custom-key-bindings () activate)
        (define-key cua--rectangle-keymap [remap move-end-of-line]         'cua-resize-rectangle-move-eol)
        (define-key cua--rectangle-keymap [remap move-beginning-of-line]   'cua-resize-rectangle-move-bol)
        (define-key cua--rectangle-keymap [remap forward-word]             'cua-resize-rectangle-right-word)
        (define-key cua--rectangle-keymap [remap backward-word]            'cua-resize-rectangle-left-word)
        (cua--rect-M/H-key ?B 'cua-blank-rectangle)
        (cua--rect-M/H-key ?b 'cua-resize-rectangle-left-word)
        (cua--rect-M/H-key ?F 'cua-fill-char-rectangle)
        (cua--rect-M/H-key ?f 'cua-resize-rectangle-right-word))))

癖のあるモジュールだけど、がんばって飼い慣らして使いましょう。

The post Emacsの範囲選択UIを大幅拡張してくれるcua-mode appeared first on 工夫と趣向と分別と。.

(defadvice kill-region
  (around kill-region-or-backward-kill-word (beg end) activate)
  (if (and (called-interactively-p 'any) (not mark-active))
      (backward-kill-word (prefix-numeric-value current-prefix-arg))
    ad-do-it))

おまけで、選択モードでないときにM-wが現在行をコピーするようにするのがこれ。（プレフィックスにも対応）

(defadvice kill-ring-save
  (around kill-ring-save-or-copy-line-as-kill (beg end) activate)
  (interactive (list (point) (mark)))
  (if (and (called-interactively-p 'any) (not mark-active))
      (copy-region-as-kill (point-at-bol 1) (point-at-eol 2))
    ad-do-it))

Emacsでイラつくことのひとつが行単位のコピー（viならY）の面倒さだが、こういう工夫で乗り越えよう。

The post Emacs: kill-region-or-backward-kill-word appeared first on 工夫と趣向と分別と。.

ところが、ターミナル（エミュレータ）上では原則として一つのキー入力は一つのASCIIコードとしてアプリケーションに渡されるため、上記のように対応するASCIIコードのないキーの組合せはEmacsなどでそれとして認識することができない。Meta+XをEscape Xの二ストロークに置換する仕掛けがせいぜいだ。

…と思いきや、実はEmacsにはいわゆるスティッキー修飾キーに相当するevent-apply-*-modifierというギミック的関数が用意されており、たとえばC-x @ c（event-apply-control-modifier）と押してからRETを押すと、C-RETを押したのと同じことになる。つまり、たとえばiTermであればPreferences→Keys→Global Shortcut Keysで+を押し、

Shortcut Keyboard:	^
Action:	Send Hex Code
	18 40 63 0d

のように設定すれば、EmacsでC-RETが効くようになる。もちろん、「18 40 63 0d」とはC-x @ c RETをASCIIコードに置き換えたものだ。C-,なども同様に設定すればいい。

ところが、C-S-SPCのような組合せはすんなりとはいかない。CとS-SPCに分解してみても、依然としてS-SPCにはASCIIコードがないのだ。CとSとSPCに分解しようと思っても、event-apply-*-modifierは直後の一ストロークに作用するので、C-x @ c C-x @ s SPCのC-x @ cの効用は直後のC-xに食われ、そこで連鎖が終了してしまう。ならばとSとC-SPCに分解してみても、C-SPCはASCIIコードでは00すなわちC-@であるため、C-S-@という組合せになってC-S-SPCとは認識されない。（ところでinput-decode-mapやkey-translation-mapを使う別解もあるが、ここでは詳しくは触れない）

解決策としては、「スティッキーControl+Shiftキー」を自作すれば良い。つまり、こんな関数を作り:

(defun event-apply-control-shift-modifier (ignore-prompt)
  "\\Add the Control+Shift modifier to the following event.
For example, type \\[event-apply-control-shift-modifier] SPC to enter Control-Shift-SPC."
  (vector (event-apply-modifier
           (event-apply-modifier (read-event) 'shift 25 "S-")
           'control 26 "C-")))
(define-key function-key-map (kbd "C-x @ C") 'event-apply-control-shift-modifier)

次のような設定を加える。

同様に、たくさん使いたいquery-replace-regexp（正規表現による文字列置換）はEmacsの標準ではC-M-%などというターミナル住民にとっては鬼畜なキーに割り当てられているわけだが、これも次のような関数を作り:

(defun event-apply-meta-control-modifier (ignore-prompt)
  "\\Add the Meta-Control modifier to the following event.
For example, type \\[event-apply-meta-control-modifier] % to enter Meta-Control-%."
  (vector (event-apply-modifier
           (event-apply-modifier (read-event) 'control 26 "C-")
           'meta 27 "M-")))
(define-key function-key-map (kbd "C-x @ M") 'event-apply-meta-control-modifier)

下のようなキー設定を加えれば良い。

世の中、カビくさい道具であってもやりようはあるもんです。どんなところでも、妥協せずに使えるものを何でも使って自らを足らしむる。それがハック。

追記：zshもマルチストロークのキーバインディングに対応しているので、たとえば上記のように設定したC-RETに機能を割り当てるには

bindkey '^X@c^M' accept-line

でOK。（上記はC-RETをRETと同じにする設定）

The post ターミナルのEmacsでも特殊キーコンボ appeared first on 工夫と趣向と分別と。.

(defadvice universal-argument-more
  (before stop-by-eight-before-sixteen (arg) activate)
  "Stop by eight before sixteen."
  (and (consp arg)
       (let ((num (car arg)))
         (if (> 16 num) (ad-set-arg 0 `(,(/ num 2)))))))

使ってみると、これがけっこうしっくり来るんだな。C-u C-uだと多すぎだからC-u+コマンドを2回、というシーンはけっこうあるので、4から16と急加速する前に8を。スペースを8個削るとか、8行分コピーするとか、なかなか手頃なサイズです。
このなかなか表面化しないフラストレーションを言葉にしてくれた同僚のK君に感謝。
2013-12-04追記: (consp arg)条件を加えないとC-u 1 0 C-u 1で1を10個入力できなくなるので修正。

The post EmacsのC-u C-uを8回繰り返しにする appeared first on 工夫と趣向と分別と。.

　どうも、あるファイルがSVKの管理下にあるかをチェックする部分がおかしい。ファイルのパスをチェックアウトディレクトリ一覧と照合するのだが、その一覧のキャッシュが利いておらず、毎回svk checkout --listを実行している。

　こいつは~/.svk/configのタイムスタンプを頼りにしているのだが、どうやら、SVKはいつごろからかsvk checkout --listを実行しただけで同ファイルが更新されるようになったらしい。SVKの方を直したい気もするが、とりあえずコマンド実行後のタイムスタンプを覚えるようにした。

　ところがやっぱりキャッシュが利かない。なんでだろうと思ったら、キャッシュを使う条件が「現在のタイムスタンプ」＜「覚えているタイムスタンプ」になっている。ウオォォォム！

　ということで修正はこう。

Index: vc-svk.el
===================================================================
--- vc-svk.el	(revision 2557)
+++ vc-svk.el	(working copy)
@@ -768,17 +768,20 @@
   (let ((config "~/.svk/config")
         mtime)
     (when (file-readable-p config)
-      (setq mtime (nth 5 (file-attributes "~/.svk/config")))
+      (setq mtime (nth 5 (file-attributes config)))
       (unless (and vc-svk-co-paths           ; has not it been loaded?
-                   (vc-svk-time-less-p mtime ; is it unmodified since?
-                                       (car vc-svk-co-paths)))
+                   (not                      ; is it unmodified since?
+                    (vc-svk-time-less-p (car vc-svk-co-paths) mtime)))
         ;; (re)load
-        (setq vc-svk-co-paths (list mtime))
         (with-temp-buffer
           (vc-svk-command t 0 nil "checkout" "--list")
+          ;; `svk checkout --list' modifies ~/.svk/config somehow, so
+          ;; you have to stat it again.
+          (setq mtime (nth 5 (file-attributes config)))
+          (setq vc-svk-co-paths (list mtime))
           (goto-char (point-min))
           (when (search-forward "==========\n" nil t)
-            (while (re-search-forward "^ +\\(.+\\) *\t\\(.+\\)$" nil t)
+            (while (re-search-forward "^ +\\(.+?\\) *\t\\(.+\\)$" nil t)
               (add-to-list 'vc-svk-co-paths
                            (list (match-string-no-properties 2)
                                  (match-string-no-properties 1))))))

　いまどきVCなんて誰も使ってないのかな。ファイルひとつだけ修正するときはPCL系より手軽でいいんだけど。

The post vc-svk.elが遅い appeared first on 工夫と趣向と分別と。.

(defun kill-region-or-backward-kill-word (&optional arg)
  "Kill a region or a word backward."
  (interactive)
  (if mark-active
      (kill-region (mark) (point))
    (backward-kill-word (or arg 1))))
(global-set-key "\C-w" 'kill-region-or-backward-kill-word)

zshで同じことをするならこう。

tcsh-backward-delete-word () {
	local WORDCHARS="${WORDCHARS:s#/#}"
	zle backward-delete-word
    }
    zle -N tcsh-backward-delete-word
    kill-region-or-tcsh-backward-delete-word () {
        if [ $MARK -eq 0 ]; then
            tcsh-backward-delete-word
        else
            zle kill-region
            MARK=0
        fi
    }
    zle -N kill-region-or-tcsh-backward-delete-word
    bindkey '^W' kill-region-or-tcsh-backward-delete-word

zshにはtransient-mark-modeはないので、マーク位置がバッファの先頭だったらマークされていないと見なす。
けっこう便利。
※その後変数REGION_ACTIVEが導入されたので、今は以下でOK。（2013-10-21追記）

kill-region-or-tcsh-backward-delete-word () {
        if ((REGION_ACTIVE)); then
            zle kill-region
        else
            tcsh-backward-delete-word
        fi
    }

The post Making Ctrl+W a tad smarter appeared first on 工夫と趣向と分別と。.

; window stuff
(define-key ctl-x-map #\3 'split-window-vertically)
(define-key ctl-x-map '(#\5 #\f) 'find-file-other-window)
(define-key ctl-x-map '(#\5 #\2) 'new-pseudo-frame)
(define-key ctl-x-map '(#\5 #\0) 'delete-pseudo-frame)
(define-key ctl-x-map '(#\5 #\o) 'next-pseudo-frame)
(define-key ctl-x-map '(#\5 #\n) 'next-pseudo-frame)
(define-key ctl-x-map '(#\5 #\p) 'previous-pseudo-frame)

(defun kill-buffer-and-window ()
  (interactive)
  (and (kill-buffer (selected-buffer)) (delete-window)))
(define-key ctl-x-map '(#\4 #\0) 'kill-buffer-and-window)

; ミニバッファのヒストリの挙動
(define-key minibuffer-local-completion-map #\Up
	    'minibuffer-previous-line-or-history)
(define-key minibuffer-local-completion-map #\Down
	    'minibuffer-next-line-or-history)
(define-key minibuffer-local-completion-map #\C-p
	    'minibuffer-previous-line-or-history)
(define-key minibuffer-local-completion-map #\C-n
	    'minibuffer-next-line-or-history)
(define-key minibuffer-local-completion-map #\C-Up
	    'minibuffer-previous-line-or-search-history)
(define-key minibuffer-local-completion-map #\C-Down
	    'minibuffer-next-line-or-search-history)

　そしてRPN電卓！Emacsにはmcalcというのがあるが、xyzzyにも移植されていたので、持ってきて設定を追加してみた。演算子を簡単に追加できるのがいいね。以下でクリップボードやキルリングとの間で数値を相互にコピペできる。

; RPN calculator
(load-library "mcalc")

(defun mcalc-copy (arglist)
  (let ((arg (nth 0 arglist)))
    (ed::kill-new (mcalc-format-string arg))
    (message "Copied")
    (list arg)))
(mcalc-add-function "w" 'mcalc-copy 1)

(defun mcalc-paste (arglist)
  (let ((arg (parse-integer (nth 0 (ed::current-kill 0)))))
    (list arg)))
(mcalc-add-function "y" 'mcalc-paste 0)

(defun mcalc-copy-to-clipboard (arglist)
  (let ((arg (nth 0 arglist)))
    (copy-to-clipboard (mcalc-format-string arg))
    (message "Copied to clipboard")
    (list arg)))
(mcalc-add-function "c" 'mcalc-copy-to-clipboard 1)

(defun mcalc-paste-from-clipboard (arglist)
  (let ((arg (parse-integer (get-clipboard-data))))
    (list arg)))
(mcalc-add-function "v" 'mcalc-paste-from-clipboard 0)

　同じことをEmacsのmcalcでやるにはこうする。Xのクリップボードの操作は面倒なのでやっていない。(kill-newにあたるものがないようだ)

(require 'mcalc)

(defun mcalc-copy (arglist)
  (let ((arg (nth 0 arglist)))
    (kill-new (mcalc-format-string arg))
    (message "Copied")
    (list arg)))
(mcalc-add-function "w" 'mcalc-copy 1)

(defun mcalc-paste (arglist)
  (let ((arg (string-to-number (current-kill 0))))
    (list arg)))
(mcalc-add-function "y" 'mcalc-paste 0)

　んー、いい感じ。

The post xyzzy / mcalc appeared first on 工夫と趣向と分別と。.

　さて、ほぼGNU Emacsでいけるようになったが、もう一つ問題があった。(setq version-control 'never)および(setq vc-make-backup-files nil)しているのに数字付きのバックアップファイルが作られる。調べてみたら、新しいVCのせいだった。新設の変数としてvc-stay-localおよび各バックエンド用のvc-{backend}-stay-localというものがあり、これがデフォルトのnon-nilだと、レポジトリにアクセスせずにローカルでdiffしたりできるよう、リビジョン番号付きのバックアップが作られるようだ。

　(setq vc-stay-local nil)とすればバックアップは抑制できるが、レポジトリアクセスが減るのは便利な気もするのでそのままにしておいた。

The post GNU Emacs 21.3.50でlookupとVC appeared first on 工夫と趣向と分別と。.

　まず、他のXクライアントからコピーするとISO-2022-JPの断片が混じったりNUL文字が入ったりする件はEmacs側のバグだったようで、最新のEmacs multi-ttyスナップショットに上げたら解消した。

　Emacsから他のXクライアントへコピーすると化ける問題とUnicodeの文字が豆腐になる問題は同根で、ただの設定不足だった。なぜかDarwinでしか実行するようになっていなかった下記を有効にしたら直った。

(if (fboundp 'utf-translate-cjk-mode)
    (utf-translate-cjk-mode 1))

　あとはlookupの外字が「■」になってしまう問題が残っている。bitmap-muleはフォントもろとも入れてあるのだが…。

The post GNU Emacs 21.3.50でのコピペとフォント問題 appeared first on 工夫と趣向と分別と。.